[tolgatt]

Hello,
i need a vbscript to list all disabled computer accounts in my win 2003 active directory domain. can anyone give me a sample code.
Thanks a lot

[Dumber]

something wrong with dsquery?
http://www.robvanderwoude.com/adshel...y_computer.txt

or is t their something wrong with the AD queries you can make via ADUC?

[tolgatt]

hello dumber thanks for reply, i want to create a script that runs everyday at 7 o clock and list me disabled computer accounts and mail them to some persons. Because of this i want to make it with scripting. How can i do it with vbscript code.i find mailing code but i couldnt find disabled account listing.

[Rems]

Related thread: userAccountControl differences

You can do the same for computer accounts,

Set objRootDSE = GetObject("LDAP://rootDSE")
strDNSDomain = objRootDSE.Get("defaultNamingContext")

'Start the ADO connection
Set objCommand = CreateObject("ADODB.Command")
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
objCommand.ActiveConnection = objConnection

'Set the ADO connection query strings
StartNode = strDNSDomain
SearchScope = "subtree"
FilterString = "(&(objectclass=computer)" _
             & "(userAccountControl:1.2.840.113556.1.4.803:=2))"
Attributes = "adspath"

'Create the LDAP-Query
LDAPQuery = "<LDAP://" & StartNode & ">;" & FilterString & ";" _
            & Attributes & ";" & SearchScope

objCommand.CommandText = LDAPQuery
objCommand.Properties("Page Size") = 100
objCommand.Properties("Timeout") = 30
objCommand.Properties("Cache Results") = False

Set objRecordSet = objCommand.Execute

If not objRecordSet.eof then 
  objRecordSet.MoveFirst
  Do Until objRecordset.EOF
    Set objItem = GetObject(objRecordSet.Fields("AdsPath").Value)
    strParentOU = Replace(objItem.parent, "LDAP://", "")

       ResultsLst = _
            ResultsLst & objItem.cn & vbTab _
             & "[" & strParentOU & "]" & vbNewLine

    Set objItem = Nothing
    objRecordSet.MoveNext
  Loop
End If


wscript.echo ResultsLst

wscript.quit

(How to query Active Directory by using a bitwise filter)


\Rems

[tolgatt]

thank you very much rems.