[tssizemore82]

I need to be able to log - Username, time and Ip address at login via a batch file. Can anyone help?

[gforceindustries]

You don't mention your Operating System...

%username%

%time%, time.exe or now.exe from the Resource Kit

Extract the required data from the output of ipconfig http://www.ericphelps.com/batch/samples/ip.txt

All of which could have been found within 5 seconds by searching this site and/or Google

[Rems]

@tssizemore82,
In order to keep the forums running well, please follow these simple rules for the forums here.
Search before you post. And, carefully write your question, provide all the necessary information.

Are the computers client in a domain?? Are the users domain users??? OSs? IP version?
You like to run the batch as logonscript? using GPOs?? Is there a networkshare to write the logs to??

Several batch samples can be found already in this scripting forum!


sample:

@echo off & cls

Set "logFile=%Computername%.log"  provide full networkpath to logfile!

::# Get IP Address
for /f "skip=1 tokens=2 delims=[]" %%* in (
   'ping.exe -n 1 %Computername%') Do (set "IP=%%*" & goto:exitFor1)
:exitFor1

::# Get Full Name of User
If /i "%USERDOMAIN%"=="%Computername%" (
   for /f "skip=1 tokens=2,* delims= " %%a in (
     'net.exe user "%Username%"') do (
       (set "DisplayName=%%b" & goto:exitFor2))
 ) Else (
   for /f "skip=3 tokens=2,* delims= " %%a in (
     'net.exe user "%Username%" /domain') do (
       (set "DisplayName=%%b" & goto:exitFor2))
 )
:exitFor2
   If defined DisplayName Set "DisplayName=%DisplayName:)=^)%"

::# Append to log
>>"%logFile%" (
   echo\*** Logon
   echo\User       : %USERDOMAIN%\%Username%  (%DisplayName%^)
   echo\Date/Time  : %date% - %time% 
   echo\To computer: %IP% (%Computername%^)
echo\-----------------------------------------------------------------)

\Rems